ISTAT Immigration

Vai alla versione italiana
Vai alla versione italiana

This dataset collects official statistical data about immigration in Italy, provided by the Italian National Institute of Statistics (dati.istat.it) . We grouped together different statistical datasets (tables) photographing different phenomena related to the topic, covering years from 1999 to 2008.

ISTAT-Immigration is the first one of a set of thematic, open license, datasets that we are making available in the form of Linked Data, to be freely reused in any sort of application.

Data is represented by means of the Data Cube vocabulary and is available as a SPARQL endpoint, as Linked Data or  as a single RDF/XML file. Read the example queries section to find out how to explore our public endpoint and embed data in your own web application.

No application built on this dataset are available at the moment. Be the first to build one and make us know about it.

Example Queries

For those not familiar with SPARQL, it might be useful to know that it is a standard, widely supported W3C query language. SPARQL queries can be performed via simple HTTP calls to said endpoints.

Info about all statistical datasets included in this LOD dataset Run query
PREFIX qb:<http://purl.org/linked-data/cube#>
PREFIX rdfs:<http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcterms:<http://purl.org/dc/terms/>
PREFIX foaf:<http://xmlns.com/foaf/0.1/>
SELECT DISTINCT ?dataset ?label ?title ?comment ?creator ?creator_page ?mantainer ?mantainer_page ?subject
WHERE { ?dataset a qb:DataSet.
	?dataset rdfs:label ?label.
		FILTER ( lang(?label) = "it" )
        ?dataset rdfs:comment ?comment.
		FILTER ( lang(?comment) = "it" )
	?dataset dcterms:title ?title.
		FILTER ( lang(?title) = "it" )
        ?dataset dcterms:creator ?c.
        ?c rdfs:label ?creator.
		FILTER ( lang(?creator) = "it" )
        ?c foaf:page ?creator_page.
	?dataset dcterms:maintainer ?m.
	?m rdfs:label ?mantainer.
		FILTER ( lang(?mantainer) = "it" )
        ?m foaf:page ?mantainer_page. }
All the dimensions used in one specific statistical dataset (DCIS_MATRIMONISTR)Run query
PREFIX qb:<http://purl.org/linked-data/cube#>
PREFIX rdfs:<http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcterms:<http://purl.org/dc/terms/>
PREFIX skos:<http://www.w3.org/2004/02/skos/core#>
SELECT ?dim ?dim_label ?dim_code_list
WHERE { ?dataset qb:structure ?dsd.
        ?dsd qb:component ?bnode.
        ?bnode qb:dimension ?dim.
	?dim skos:prefLabel ?dim_label.
		FILTER ( lang(?dim_label) = "it" )
        ?dim qb:codeList ?dim_code_list.
        ?dataset rdfs:label "DCIS_MATRIMONISTR"@en.
        ?dataset dcterms:title ?dataset_title}
All possible values of the istat:dimension-paesi dimensionRun query
PREFIX qb:<http://purl.org/linked-data/cube#>
PREFIX skos:<http://www.w3.org/2004/02/skos/core#>
PREFIX istat:<http://data.linkedopendata.it/istat/resource/>
SELECT DISTINCT ?id ?label ?notation
WHERE {
	istat:dimension-paesi qb:codeList ?code_list .
	?code_list skos:hasTopConcept ?value .
	?id skos:prefLabel ?label .
		FILTER ( lang(?label) = "it" )
	?id skos:notation ?notation .
}
All the places where in 2008 less than 200, 30 years old  foreigners were living. - Run query
PREFIX qb:<http://purl.org/linked-data/cube#>
PREFIX skos:<http://www.w3.org/2004/02/skos/core#>
PREFIX istat:<http://data.linkedopendata.it/istat/resource/>
SELECT DISTINCT ?terr ?value
WHERE {
	?obs qb:dataset istat:dataset-DCIS_POPSTRRES .
	?obs istat:dimension-eta istat:code-eta-30 .
	?obs istat:dimension-sexistat1 istat:code-sexistat1-1 .
	?obs istat:measure-DCIS_POPSTRRES ?value .
	FILTER (?value < 200)
	?obs istat:dimension-time istat:code-time-2008 .
	?obs istat:dimension-itter107 ?t .
	?t skos:prefLabel ?terr .
	FILTER langMatches( lang(?terr), "it" )
}
Number of male resident foreigners vs. number of children born from foreign father.Run query
PREFIX qb:<http://purl.org/linked-data/cube#>
PREFIX skos:<http://www.w3.org/2004/02/skos/core#>
PREFIX istat:<http://data.linkedopendata.it/istat/resource/>
SELECT DISTINCT ?terr ?stranieri_maschi ?nati_da_coppie_padre_str
WHERE {
	?obs1 qb:dataset istat:dataset-DCIS_POPSTRRES .
	?obs1 istat:dimension-eta istat:code-eta-999 .
	?obs1 istat:dimension-sexistat1 istat:code-sexistat1-1 .
	?obs1 istat:measure-DCIS_POPSTRRES ?stranieri_maschi .
	?obs1 istat:dimension-time istat:code-time-2008 .
	?obs1 istat:dimension-itter107 ?t .
	?t skos:prefLabel ?terr .
		FILTER langMatches( lang(?terr), "it" )

	?obs2 qb:dataset istat:dataset-DCIS_NATIPADSTR .
	?obs2 istat:dimension-itter107 ?t .
	?obs2 istat:dimension-statciv2 istat:code-statciv2-99 .
	?obs2 istat:dimension-tipgenitoristr istat:code-tipgenitoristr-6 .
	?obs2 istat:measure-DCIS_NATIPADSTR ?nati_da_coppie_padre_str .
	?obs2 istat:dimension-time istat:code-time-2008 . }
ORDER BY DESC(?stranieri_maschi)

Dataset Linked Data

Nome: ISTAT Immigration
Licenza: cc-by
Autore della trasformazione: Linkedopendata.it
Data ultimo aggiornamento: 09 Jun 2011
Star-Rating (?): 5 stelle linkeddata
Sparql endpoint: http://sparql.linkedopendata.it/istat
Dimensione in Mb: 700
Homepage/Ulteriori informazioni: http://www.linkedopendata.it/istat-immigration

Dataset di origine

Nome del dataset originale: dati.istat.it
Formato: xml
Licenza: cc-by
Autore: ISTAT
Mantainer: ISTAT