ISTAT Immigrazione

English version of this page
Switch to English

Questo dataset contiene dati ufficiali raccolti dall’Istituto Nazionale di Statistica Italiano riguardanti il tema dell’immigrazione. Il dataset si compone di diversi insiemi di rilevazioni statistiche, diversi per grandezza misurata e copertura temporale. Le rilevazioni includono (si veda dati.istat.it per ulteriori informazioni ):

  • Matrimoni con almeno uno sposo straniero
  • Stima dei nati con almeno un genitore straniero
  • Nati da coppie con almeno la madre straniera
  • Nati da coppie con almeno il padre straniero
  • Popolazione straniera residente cancellata dalle anagrafi per trasferimento di residenza
  • Popolazione straniera residente iscritta per trasferimento di residenza
  • Popolazione straniera residente – bilancio
  • Popolazione staniera residente
  • Popolazione straniera residente al 1° gennaio

ISTAT-Immigrazione è il primo di una serie di dataset tematici che ci proponiamo di rendere pubblici e immediatamente utilizzabili sia da curiosi che da analisti e sviluppatori.

I dati sono espressi in RDF, in conformità con il vocabolario Data Cube per rappresentare dati multidimensionali, e disponibili su SPARQL endpoint, in modalità Linked Data o come un singolo file RDF/XML. Leggi la sezione query di esempio per scoprire come interrogare ed incrociare i dati dalla tua applicazione web.

Applicazioni (Hai usato i dati? Segnalaci la tua applicazione!)

Nessuna applicazione disponibile al momento.


Query di esempio (come si interroga il dataset)

Di seguito alcuni esempi di query SPARQL su questo dataset.
Tutti i dataset statistici e loro caratteristiche principali – Lancia query
PREFIX qb:<http://purl.org/linked-data/cube#>
PREFIX rdfs:<http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcterms:<http://purl.org/dc/terms/>
PREFIX foaf:<http://xmlns.com/foaf/0.1/>
SELECT DISTINCT ?dataset ?label ?title ?comment ?creator ?creator_page ?mantainer ?mantainer_page ?subject
WHERE { ?dataset a qb:DataSet.
	?dataset rdfs:label ?label.
		FILTER ( lang(?label) = "it" )
        ?dataset rdfs:comment ?comment.
		FILTER ( lang(?comment) = "it" )
	?dataset dcterms:title ?title.
		FILTER ( lang(?title) = "it" )
        ?dataset dcterms:creator ?c.
        ?c rdfs:label ?creator.
		FILTER ( lang(?creator) = "it" )
        ?c foaf:page ?creator_page.
	?dataset dcterms:maintainer ?m.
	?m rdfs:label ?mantainer.
		FILTER ( lang(?mantainer) = "it" )
        ?m foaf:page ?mantainer_page. }
Tutte le dimensioni utilizzate in un singolo dataset statistico (DCIS_MATRIMONISTR)Lancia query
PREFIX qb:<http://purl.org/linked-data/cube#>
PREFIX rdfs:<http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcterms:<http://purl.org/dc/terms/>
PREFIX skos:<http://www.w3.org/2004/02/skos/core#>
SELECT ?dim ?dim_label ?dim_code_list
WHERE { ?dataset qb:structure ?dsd.
        ?dsd qb:component ?bnode.
        ?bnode qb:dimension ?dim.
	?dim skos:prefLabel ?dim_label.
        ?dim qb:codeList ?dim_code_list.
        ?dataset rdfs:label "DCIS_MATRIMONISTR"@en.
        ?dataset dcterms:title ?dataset_title}
I possibili valori della dimensione istat:dimension-paesiLancia query
PREFIX qb:<http://purl.org/linked-data/cube#>
PREFIX skos:<http://www.w3.org/2004/02/skos/core#>
PREFIX istat:<http://data.linkedopendata.it/istat/resource/>
SELECT DISTINCT ?id ?label ?notation
WHERE {
	istat:dimension-paesi qb:codeList ?code_list .
	?code_list skos:hasTopConcept ?value .
	?id skos:prefLabel ?label .
		FILTER ( lang(?label) = "it" )
	?id skos:notation ?notation .
}
Tutte i territori che nel 2008 avevano meno di 200 stranieri residenti di 30 anni di età. – Lancia query
PREFIX qb:<http://purl.org/linked-data/cube#>
PREFIX skos:<http://www.w3.org/2004/02/skos/core#>
PREFIX istat:<http://data.linkedopendata.it/istat/resource/>
SELECT DISTINCT ?terr ?value
WHERE {
	?obs qb:dataset istat:dataset-DCIS_POPSTRRES .
	?obs istat:dimension-eta istat:code-eta-30 .
	?obs istat:dimension-sexistat1 istat:code-sexistat1-1 .
	?obs istat:measure-DCIS_POPSTRRES ?value .
	FILTER (?value < 200)
	?obs istat:dimension-time istat:code-time-2008 .
	?obs istat:dimension-itter107 ?t .
	?t skos:prefLabel ?terr .
	FILTER langMatches( lang(?terr), "it" )
}


Numero di residenti stranieri maschi e numero di nati da coppie con padre straniero. - Lancia query
PREFIX qb:<http://purl.org/linked-data/cube#>
PREFIX skos:<http://www.w3.org/2004/02/skos/core#>
PREFIX istat:<http://data.linkedopendata.it/istat/resource/>
SELECT DISTINCT ?terr ?stranieri_maschi ?nati_da_coppie_padre_str
WHERE {
	?obs1 qb:dataset istat:dataset-DCIS_POPSTRRES .
	?obs1 istat:dimension-eta istat:code-eta-999 .
	?obs1 istat:dimension-sexistat1 istat:code-sexistat1-1 .
	?obs1 istat:measure-DCIS_POPSTRRES ?stranieri_maschi .
	?obs1 istat:dimension-time istat:code-time-2008 .
	?obs1 istat:dimension-itter107 ?t .
	?t skos:prefLabel ?terr .
		FILTER langMatches( lang(?terr), "it" )

	?obs2 qb:dataset istat:dataset-DCIS_NATIPADSTR .
	?obs2 istat:dimension-itter107 ?t .
	?obs2 istat:dimension-statciv2 istat:code-statciv2-99 .
	?obs2 istat:dimension-tipgenitoristr istat:code-tipgenitoristr-6 .
	?obs2 istat:measure-DCIS_NATIPADSTR ?nati_da_coppie_padre_str .
	?obs2 istat:dimension-time istat:code-time-2008 . }
ORDER BY DESC(?stranieri_maschi)

Dataset Linked Data

Nome: ISTAT Immigrazione
Licenza: cc-by
Autore della trasformazione: Linkedopendata.it
Data ultimo aggiornamento: 08 Jun 2011
Star-Rating (?): 5 stelle linkeddata
Sparql endpoint: http://sparql.linkedopendata.it/istat
Dimensione in Mb: 700
Homepage/Ulteriori informazioni: http://www.linkedopendata.it/istat-immigrazione

Dataset di origine

Nome del dataset originale: Dati Istat
Formato: altro
Licenza: cc-by
Autore: ISTAT
Mantainer: ISTAT